1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
|
"=============================================================================
" FILE: handler.vim
" AUTHOR: Shougo Matsushita <Shougo.Matsu at gmail.com>
" License: MIT license
"=============================================================================
function! deoplete#handler#_init() abort
augroup deoplete
autocmd!
autocmd InsertLeave * call s:on_insert_leave()
autocmd CompleteDone * call s:on_complete_done()
autocmd TextChangedI * call s:completion_begin('TextChangedI')
autocmd InsertEnter *
\ call s:completion_begin('InsertEnter') | call s:timer_begin()
autocmd InsertLeave * call s:timer_end()
autocmd VimLeavePre * call s:on_vimleave()
augroup END
for event in ['BufNewFile', 'BufRead', 'BufWritePost']
execute 'autocmd deoplete' event '* call s:on_event('.string(event).')'
endfor
if g:deoplete#enable_refresh_always
autocmd deoplete InsertCharPre * call s:completion_begin('InsertCharPre')
endif
endfunction
function! s:do_complete(timer) abort
let context = g:deoplete#_context
if get(context, 'event', '') !=# 'InsertEnter' && mode() !=# 'i'
call s:timer_end()
return
endif
if !has_key(context, 'candidates')
\ || empty(context.candidates)
\ || (context.event !=# 'Manual'
\ && s:prev_completion.complete_position == getpos('.')
\ && s:prev_completion.candidates ==# context.candidates)
return
endif
if deoplete#util#get_input(context.event) !=# context.input
let s:prev_completion.candidates = []
let s:prev_completion.complete_position = getpos('.')
return
endif
if context.event ==# 'Manual'
" Disable the manual completion
let context.event = ''
elseif !exists('g:deoplete#_saved_completeopt')
call deoplete#mapping#_set_completeopt()
endif
if g:deoplete#complete_method ==# 'complete'
call feedkeys("\<Plug>_")
elseif g:deoplete#complete_method ==# 'completefunc'
let &l:completefunc = 'deoplete#mapping#_completefunc'
call feedkeys("\<C-x>\<C-u>", 'n')
elseif g:deoplete#complete_method ==# 'omnifunc'
let &l:omnifunc = 'deoplete#mapping#_completefunc'
call feedkeys("\<C-x>\<C-o>", 'n')
endif
let s:prev_completion.candidates = context.candidates
let s:prev_completion.complete_position = getpos('.')
endfunction
function! s:timer_begin() abort
if exists('s:completion_timer')
return
endif
let delay = max([50, g:deoplete#auto_complete_delay])
let s:completion_timer = timer_start(delay,
\ function('s:do_complete'), {'repeat': -1})
let s:prev_completion = { 'complete_position': [], 'candidates': [] }
endfunction
function! s:timer_end() abort
if !exists('s:completion_timer')
return
endif
call timer_stop(s:completion_timer)
unlet s:completion_timer
endfunction
function! deoplete#handler#_async_timer_start() abort
if exists('s:async_timer')
call deoplete#handler#_async_timer_stop()
endif
let s:async_timer = { 'event': 'Async', 'changedtick': b:changedtick }
let s:async_timer.id = timer_start(
\ max([50, g:deoplete#auto_refresh_delay]),
\ function('s:completion_async'), {'repeat': -1})
endfunction
function! deoplete#handler#_async_timer_stop() abort
if exists('s:async_timer')
call timer_stop(s:async_timer.id)
unlet s:async_timer
endif
endfunction
function! s:completion_async(timer) abort
if mode() !=# 'i'
call deoplete#handler#_async_timer_stop()
return
endif
call s:completion_begin(s:async_timer.event)
endfunction
function! s:completion_begin(event) abort
if !exists('g:deoplete#_initialized')
return
endif
let context = deoplete#init#_context(a:event, [])
if s:is_skip(a:event, context)
call deoplete#mapping#_restore_completeopt()
let g:deoplete#_context.candidates = []
return
endif
" Call omni completion
for filetype in context.filetypes
for pattern in deoplete#util#convert2list(
\ deoplete#util#get_buffer_config(filetype,
\ 'b:deoplete_omni_patterns',
\ 'g:deoplete#omni_patterns',
\ 'g:deoplete#_omni_patterns'))
if pattern !=# '' && &l:omnifunc !=# ''
\ && context.input =~# '\%('.pattern.'\)$'
call deoplete#mapping#_set_completeopt()
call feedkeys("\<C-x>\<C-o>", 'n')
return
endif
endfor
endfor
call rpcnotify(g:deoplete#_channel_id,
\ 'deoplete_auto_completion_begin', context)
endfunction
function! s:is_skip(event, context) abort
if s:is_skip_text(a:event)
return 1
endif
let disable_auto_complete =
\ deoplete#util#get_simple_buffer_config(
\ 'b:deoplete_disable_auto_complete',
\ 'g:deoplete#disable_auto_complete')
if &paste
\ || (a:event !=# 'Manual' && disable_auto_complete)
\ || (&l:completefunc !=# '' && &l:buftype =~# 'nofile')
\ || (a:event !=# 'InsertEnter' && mode() !=# 'i')
return 1
endif
return 0
endfunction
function! s:is_skip_text(event) abort
let context = g:deoplete#_context
let input = deoplete#util#get_input(a:event)
if has_key(context, 'input')
\ && a:event !=# 'Manual'
\ && a:event !=# 'Async'
\ && input ==# context.input
return 1
endif
let displaywidth = strdisplaywidth(input) + 1
if &l:formatoptions =~# '[tca]' && &l:textwidth > 0
\ && displaywidth >= &l:textwidth
if &l:formatoptions =~# '[ta]'
\ || !empty(filter(deoplete#util#get_syn_names(),
\ "v:val ==# 'Comment'"))
return 1
endif
endif
let skip_chars = deoplete#util#get_simple_buffer_config(
\ 'b:deoplete_skip_chars', 'g:deoplete#skip_chars')
return (!pumvisible() && virtcol('.') != displaywidth)
\ || (a:event !=# 'Manual' && input !=# ''
\ && index(skip_chars, input[-1:]) >= 0)
endfunction
function! s:on_event(event) abort
if !exists('g:deoplete#_initialized')
return
endif
let context = deoplete#init#_context(a:event, [])
call rpcnotify(g:deoplete#_channel_id, 'deoplete_on_event', context)
endfunction
function! s:on_insert_leave() abort
call deoplete#mapping#_restore_completeopt()
let g:deoplete#_context = {}
endfunction
function! s:on_complete_done() abort
if get(v:completed_item, 'word', '') !=# ''
let word = v:completed_item.word
if !has_key(g:deoplete#_rank, word)
let g:deoplete#_rank[word] = 1
else
let g:deoplete#_rank[word] += 1
endif
endif
if !g:deoplete#enable_refresh_always
call deoplete#handler#_skip_next_completion()
endif
endfunction
function! s:on_vimleave() abort
if exists('g:deoplete#_channel_id')
call rpcstop(g:deoplete#_channel_id)
endif
endfunction
function! deoplete#handler#_skip_next_completion() abort
if !exists('g:deoplete#_context')
return
endif
let input = deoplete#util#get_input('CompleteDone')
if input[-1:] !=# '/'
let g:deoplete#_context.input = input
endif
endfunction
|
