Add jq linter for JSON diagnostics

1 files changed, 34 insertions, 0 deletions

diff --git a/ale_linters/json/jq.vim b/ale_linters/json/jq.vim
new file mode 100644
index 00000000..4cce0e98
--- /dev/null
+++ b/ale_linters/json/jq.vim
@@ -0,0 +1,34 @@
+" Author: jD91mZM2 <me@krake.one>
+
+call ale#Set('json_jq_executable', 'jq')
+
+function! ale_linters#json#jq#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'json_jq_executable')
+
+    return ale#Var(a:buffer, 'json_jq_executable')
+endfunction
+
+function! ale_linters#json#jq#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    " parse error: Expected another key-value pair at line 4, column 3
+    let l:pattern = '^parse error: \(.\+\) at line \(\d\+\), column \(\d\+\)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        call add(l:output, {
+        \   'text': l:match[1],
+        \   'lnum': l:match[2] + 0,
+        \   'col': l:match[3] + 0,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('json', {
+\   'name': 'jq',
+\   'executable': { b -> ale#Var(b, 'json_jq_executable') },
+\   'output_stream': 'stderr',
+\   'command': function('ale_linters#json#jq#GetCommand'),
+\   'callback': 'ale_linters#json#jq#Handle',
+\})