#208 Automatically detect pylint in virtualenv directories

10 files changed, 113 insertions, 0 deletions

diff --git a/ale_linters/python/pylint.vim b/ale_linters/python/pylint.vim
index 217fcc47..3ee8bb02 100644
--- a/ale_linters/python/pylint.vim
+++ b/ale_linters/python/pylint.vim
@@ -7,7 +7,21 @@ let g:ale_python_pylint_executable =
 let g:ale_python_pylint_options =
 \   get(g:, 'ale_python_pylint_options', '')
 
+let g:ale_python_pylint_use_global = get(g:, 'ale_python_pylint_use_global', 0)
+
 function! ale_linters#python#pylint#GetExecutable(buffer) abort
+    if !ale#Var(a:buffer, 'python_pylint_use_global')
+        let l:virtualenv = ale#python#FindVirtualenv(a:buffer)
+
+        if !empty(l:virtualenv)
+            let l:ve_pylint = l:virtualenv . '/bin/pylint'
+
+            if executable(l:ve_pylint)
+                return l:ve_pylint
+            endif
+        endif
+    endif
+
     return ale#Var(a:buffer, 'python_pylint_executable')
 endfunction
 
diff --git a/autoload/ale/python.vim b/autoload/ale/python.vim
index 34b35ddb..2c0c9d81 100644
--- a/autoload/ale/python.vim
+++ b/autoload/ale/python.vim
@@ -1,2 +1,29 @@
 " Author: w0rp <devw0rp@gmail.com>
 " Description: Functions for integrating with Python linters.
+
+" Given a buffer number, find the project root directory for Python.
+" The root directory is defined as the first directory found while searching
+" upwards through paths, including the current directory, until a path
+" containing no __init__.py files is found.
+function! ale#python#FindProjectRoot(buffer) abort
+    for l:path in ale#path#Upwards(expand('#' . a:buffer . ':p:h'))
+        if !filereadable(l:path . '/__init__.py')
+            return l:path
+        endif
+    endfor
+
+    return ''
+endfunction
+
+" Given a buffer number, find a virtualenv path for Python.
+function! ale#python#FindVirtualenv(buffer) abort
+    for l:path in ale#path#Upwards(expand('#' . a:buffer . ':p:h'))
+        let l:matches = globpath(l:path, '*/bin/activate', 0, 1)
+
+        if !empty(l:matches)
+            return fnamemodify(l:matches[-1], ':h:h')
+        endif
+    endfor
+
+    return ''
+endfunction
diff --git a/doc/ale-python.txt b/doc/ale-python.txt
index 381ca7ce..6b4a4ea4 100644
--- a/doc/ale-python.txt
+++ b/doc/ale-python.txt
@@ -72,5 +72,17 @@ g:ale_python_pylint_options                       *g:ale_python_pylint_options*
   `python3 -m pip install --user pylint`).
 
 
+g:ale_python_pylint_use_global                 *g:ale_python_pylint_use_global*
+                                               *b:ale_python_pylint_use_global*
+  Type: |Number|
+  Default: `0`
+
+  This variable controls whether or not ALE will search pylint in a virtualenv
+  directory first. If this variable is set to `1`, then ALE will always use
+  |g:ale_python_pylint_executable| for the executable path.
+
+  Both variables can be set with `b:` buffer variables instead.
+
+
 -------------------------------------------------------------------------------
   vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:
diff --git a/test/command_callback/python_paths/no_virtualenv/subdir/foo/__init__.py b/test/command_callback/python_paths/no_virtualenv/subdir/foo/__init__.py
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/no_virtualenv/subdir/foo/__init__.py
diff --git a/test/command_callback/python_paths/no_virtualenv/subdir/foo/bar.py b/test/command_callback/python_paths/no_virtualenv/subdir/foo/bar.py
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/no_virtualenv/subdir/foo/bar.py
diff --git a/test/command_callback/python_paths/with_virtualenv/env/bin/activate b/test/command_callback/python_paths/with_virtualenv/env/bin/activate
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/with_virtualenv/env/bin/activate
diff --git a/test/command_callback/python_paths/with_virtualenv/env/bin/pylint b/test/command_callback/python_paths/with_virtualenv/env/bin/pylint
new file mode 100755
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/with_virtualenv/env/bin/pylint
diff --git a/test/command_callback/python_paths/with_virtualenv/subdir/foo/__init__.py b/test/command_callback/python_paths/with_virtualenv/subdir/foo/__init__.py
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/with_virtualenv/subdir/foo/__init__.py
diff --git a/test/command_callback/python_paths/with_virtualenv/subdir/foo/bar.py b/test/command_callback/python_paths/with_virtualenv/subdir/foo/bar.py
new file mode 100644
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/with_virtualenv/subdir/foo/bar.py
diff --git a/test/command_callback/test_pylint_command_callback.vader b/test/command_callback/test_pylint_command_callback.vader
new file mode 100644
index 00000000..bd57a828
--- /dev/null
+++ b/test/command_callback/test_pylint_command_callback.vader
@@ -0,0 +1,60 @@
+Before:
+  runtime ale_linters/python/pylint.vim
+  silent! execute 'cd /testplugin/test/command_callback'
+  let g:dir = getcwd()
+  let b:command_tail = ' --output-format text --msg-template="{path}:{line}:{column}: {msg_id} ({symbol}) {msg}" --reports n %t'
+
+After:
+  silent execute 'cd ' . fnameescape(g:dir)
+  unlet! g:dir
+
+  call ale#linter#Reset()
+  let g:ale_python_pylint_executable = 'pylint'
+  let g:ale_python_pylint_options = ''
+  let g:ale_python_pylint_use_global = 0
+
+Execute(The pylint callbacks should return the correct default values):
+  AssertEqual
+  \ 'pylint',
+  \ ale_linters#python#pylint#GetExecutable(bufnr(''))
+  AssertEqual
+  \ 'pylint ' . b:command_tail,
+  \ ale_linters#python#pylint#GetCommand(bufnr(''))
+
+Execute(The pylint command callback should let you set options):
+  let g:ale_python_pylint_options = '--some-option'
+
+  AssertEqual
+  \ 'pylint --some-option' . b:command_tail,
+  \ ale_linters#python#pylint#GetCommand(bufnr(''))
+
+Execute(The pylint callbacks shouldn't detect virtualenv directories where they don't exist):
+  silent execute 'file ' . fnameescape(g:dir . '/python_paths/no_virtualenv/subdir/foo/bar.py')
+
+  AssertEqual
+  \ 'pylint',
+  \ ale_linters#python#pylint#GetExecutable(bufnr(''))
+  AssertEqual
+  \ 'pylint ' . b:command_tail,
+  \ ale_linters#python#pylint#GetCommand(bufnr(''))
+
+Execute(The pylint callbacks should detect virtualenv directories):
+  silent execute 'file ' . fnameescape(g:dir . '/python_paths/with_virtualenv/subdir/foo/bar.py')
+
+  AssertEqual
+  \ g:dir . '/python_paths/with_virtualenv/env/bin/pylint',
+  \ ale_linters#python#pylint#GetExecutable(bufnr(''))
+  AssertEqual
+  \ g:dir . '/python_paths/with_virtualenv/env/bin/pylint ' . b:command_tail,
+  \ ale_linters#python#pylint#GetCommand(bufnr(''))
+
+Execute(You should able able to use the global pylint instead):
+  silent execute 'file ' . fnameescape(g:dir . '/python_paths/with_virtualenv/subdir/foo/bar.py')
+  let g:ale_python_pylint_use_global = 1
+
+  AssertEqual
+  \ 'pylint',
+  \ ale_linters#python#pylint#GetExecutable(bufnr(''))
+  AssertEqual
+  \ 'pylint ' . b:command_tail,
+  \ ale_linters#python#pylint#GetCommand(bufnr(''))