Merge pull request #578 from nOkuda/master

Translate pylint output column to 1-based index

2 files changed, 87 insertions, 1 deletions

diff --git a/ale_linters/python/pylint.vim b/ale_linters/python/pylint.vim
index cce28479..b8e5d817 100644
--- a/ale_linters/python/pylint.vim
+++ b/ale_linters/python/pylint.vim
@@ -32,10 +32,43 @@ function! ale_linters#python#pylint#GetCommand(buffer) abort
     \   . ' %s'
 endfunction
 
+function! ale_linters#python#pylint#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " test.py:4:4: W0101 (unreachable) Unreachable code
+    let l:pattern = '\v^[^:]+:(\d+):(\d+): ([[:alnum:]]+) \((.*)\) (.*)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        "let l:failed = append(0, l:match)
+        let l:code = l:match[3]
+
+        if (l:code ==# 'C0303')
+        \ && !ale#Var(a:buffer, 'warn_about_trailing_whitespace')
+            " Skip warnings for trailing whitespace if the option is off.
+            continue
+        endif
+
+        if l:code ==# 'I0011'
+            " Skip 'Locally disabling' message
+             continue
+        endif
+
+        call add(l:output, {
+        \   'lnum': l:match[1] + 0,
+        \   'col': l:match[2] + 1,
+        \   'text': l:code . ': ' . l:match[5],
+        \   'type': l:code[:0] ==# 'E' ? 'E' : 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
 call ale#linter#Define('python', {
 \   'name': 'pylint',
 \   'executable_callback': 'ale_linters#python#pylint#GetExecutable',
 \   'command_callback': 'ale_linters#python#pylint#GetCommand',
-\   'callback': 'ale#handlers#python#HandlePEP8Format',
+\   'callback': 'ale_linters#python#pylint#Handle',
 \   'lint_file': 1,
 \})
diff --git a/test/handler/test_pylint_handler.vader b/test/handler/test_pylint_handler.vader
new file mode 100644
index 00000000..590a795f
--- /dev/null
+++ b/test/handler/test_pylint_handler.vader
@@ -0,0 +1,53 @@
+Before:
+  runtime ale_linters/python/pylint.vim
+
+After:
+  call ale#linter#Reset()
+  silent file something_else.py
+
+Execute(pylint handler parsing, translating columns to 1-based index):
+  AssertEqual
+  \ [
+  \   {
+  \     'lnum': 4,
+  \     'col': 1,
+  \     'text': 'C0303: Trailing whitespace',
+  \     'type': 'W',
+  \   },
+  \   {
+  \     'lnum': 1,
+  \     'col': 1,
+  \     'text': 'C0111: Missing module docstring',
+  \     'type': 'W',
+  \   },
+  \   {
+  \     'lnum': 2,
+  \     'col': 1,
+  \     'text': 'C0111: Missing function docstring',
+  \     'type': 'W',
+  \   },
+  \   {
+  \     'lnum': 3,
+  \     'col': 5,
+  \     'text': 'E0103: ''break'' not properly in loop',
+  \     'type': 'E',
+  \   },
+  \   {
+  \     'lnum': 4,
+  \     'col': 5,
+  \     'text': 'W0101: Unreachable code',
+  \     'type': 'W',
+  \   },
+  \ ],
+  \ ale_linters#python#pylint#Handle(bufnr(''), [
+  \ 'No config file found, using default configuration',
+  \ '************* Module test',
+  \ 'test.py:4:0: C0303 (trailing-whitespace) Trailing whitespace',
+  \ 'test.py:1:0: C0111 (missing-docstring) Missing module docstring',
+  \ 'test.py:2:0: C0111 (missing-docstring) Missing function docstring',
+  \ 'test.py:3:4: E0103 (not-in-loop) ''break'' not properly in loop',
+  \ 'test.py:4:4: W0101 (unreachable) Unreachable code',
+  \ '',
+  \ '------------------------------------------------------------------',
+  \ 'Your code has been rated at 0.00/10 (previous run: 2.50/10, -2.50)',
+  \ ])