From 5fcb24bb3e5d86da394ee1ba95fa0cea8e00ffff Mon Sep 17 00:00:00 2001
From: Jeffrey Lau <who.else.at.jlau.tk>
Date: Mon, 27 May 2019 20:06:57 +0800
Subject: Add linter for Scala Metals

https://scalameta.org/metals/
---
 ale_linters/scala/metals.vim | 48 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 ale_linters/scala/metals.vim

(limited to 'ale_linters/scala/metals.vim')

diff --git a/ale_linters/scala/metals.vim b/ale_linters/scala/metals.vim
new file mode 100644
index 00000000..f78c7119
--- /dev/null
+++ b/ale_linters/scala/metals.vim
@@ -0,0 +1,48 @@
+" Author: Jeffrey Lau - https://github.com/zoonfafer
+" Description: Metals Language Server for Scala https://scalameta.org/metals/
+
+call ale#Set('scala_metals_executable', 'metals-vim')
+call ale#Set('scala_metals_project_root', '')
+
+function! ale_linters#scala#metals#GetProjectRoot(buffer) abort
+    let l:project_root = ale#Var(a:buffer, 'scala_metals_project_root')
+
+    if !empty(l:project_root)
+        return l:project_root
+    endif
+
+    let l:potential_roots = [
+    \   'build.sc',
+    \   'build.sbt',
+    \   '.bloop',
+    \   '.metals',
+    \]
+
+    for l:root in l:potential_roots
+        let l:project_root = ale#path#ResolveLocalPath(
+        \   a:buffer,
+        \   l:root,
+        \   ''
+        \)
+
+        if !empty(l:project_root)
+            return fnamemodify(
+            \   l:project_root,
+            \   ':h',
+            \)
+        endif
+    endfor
+endfunction
+
+function! ale_linters#scala#metals#GetCommand(buffer) abort
+    return '%e' . ale#Pad('stdio')
+endfunction
+
+call ale#linter#Define('scala', {
+\   'name': 'metals',
+\   'lsp': 'stdio',
+\   'language': 'scala',
+\   'executable': {b -> ale#Var(b, 'scala_metals_executable')},
+\   'command': function('ale_linters#scala#metals#GetCommand'),
+\   'project_root': function('ale_linters#scala#metals#GetProjectRoot'),
+\})
-- 
cgit v1.2.3