From 11c11e578f22cda52048fdec1354f9675b413495 Mon Sep 17 00:00:00 2001
From: w0rp <devw0rp@gmail.com>
Date: Fri, 9 Sep 2016 00:23:26 +0100
Subject: Add linting with eslint in NeoVim, with a few bugs.

---
 ale_linters/javascript/eslint.vim | 41 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 ale_linters/javascript/eslint.vim

(limited to 'ale_linters/javascript/eslint.vim')

diff --git a/ale_linters/javascript/eslint.vim b/ale_linters/javascript/eslint.vim
new file mode 100644
index 00000000..d6763eef
--- /dev/null
+++ b/ale_linters/javascript/eslint.vim
@@ -0,0 +1,41 @@
+if exists('g:loaded_ale_linters_javascript_eslint')
+    finish
+endif
+
+let g:loaded_ale_linters_javascript_eslint = 1
+
+function! ale_linters#javascript#eslint#Handle(lines)
+    " Matches patterns line the following:
+    "
+    " <text>:47:14: Missing trailing comma. [Warning/comma-dangle]
+    " <text>:56:41: Missing semicolon. [Error/semi]
+    let pattern = '^<text>:\(\d\+\):\(\d\+\): \(.\+\) \[\(.\+\)/\(.\+\)\]'
+    let output = []
+
+    for line in a:lines
+        let match = matchlist(line, pattern)
+
+        if len(match) == 0
+            break
+        endif
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(output, {
+        \   'bufnr': bufnr('%'),
+        \   'lnum': match[1] + 0,
+        \   'vcol': 0,
+        \   'col': match[2] + 0,
+        \   'text': match[3] . '(' . match[5] . ')',
+        \   'type': match[4] ==# 'Warning' ? 'W' : 'E',
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('javascript', {
+\   'executable': 'eslint',
+\   'command': 'eslint -f unix --stdin',
+\   'callback': 'ale_linters#javascript#eslint#Handle',
+\})
-- 
cgit v1.2.3