From e5e851fadc41c55727f801ce8feacd2bd53e2aac Mon Sep 17 00:00:00 2001
From: yen3 <yen3rc@gmail.com>
Date: Mon, 30 Nov 2020 09:05:33 +0100
Subject: Add linter for haskell-language-server

The patch adds a new linter for haskell-language-server (hls). hls is
the integration point of haskell-ide-engine (hie) and ghcide.
---
 ale_linters/haskell/hls.vim | 63 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 ale_linters/haskell/hls.vim

(limited to 'ale_linters/haskell')

diff --git a/ale_linters/haskell/hls.vim b/ale_linters/haskell/hls.vim
new file mode 100644
index 00000000..ae0556a4
--- /dev/null
+++ b/ale_linters/haskell/hls.vim
@@ -0,0 +1,63 @@
+" Author: Yen3 <yen3rc@gmail.com>
+" Description: A language server for haskell
+"              The file is based on hie.vim (author: Luxed
+"              <devildead13@gmail.com>).  It search more project root files.
+"
+call ale#Set('haskell_hls_executable', 'haskell-language-server-wrapper')
+
+function! ale_linters#haskell#hls#FindRootFile(buffer) abort
+    let l:serach_root_files = [
+    \ 'stack.yaml',
+    \ 'cabal.project',
+    \ 'package.yaml',
+    \ 'hie.yaml'
+    \ ]
+
+    for l:path in ale#path#Upwards(expand('#' . a:buffer . ':p:h'))
+        for l:root_file in l:serach_root_files
+            if filereadable(l:path . l:root_file)
+                return l:path
+            endif
+        endfor
+    endfor
+
+    return ''
+endfunction
+
+function! ale_linters#haskell#hls#GetProjectRoot(buffer) abort
+    " Search for the project file first
+    let l:project_file = ale_linters#haskell#hls#FindRootFile(a:buffer)
+
+    " If it's empty, search for the cabal file
+    if empty(l:project_file)
+        " Search all of the paths except for the root filesystem path.
+        let l:paths = join(
+        \   ale#path#Upwards(expand('#' . a:buffer . ':p:h'))[:-2],
+        \   ','
+        \)
+        let l:project_file = globpath(l:paths, '*.cabal')
+    endif
+
+    " If we still can't find one, use the current file.
+    if empty(l:project_file)
+        let l:project_file = expand('#' . a:buffer . ':p')
+    endif
+
+    return fnamemodify(l:project_file, ':h')
+endfunction
+
+function! ale_linters#haskell#hls#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'haskell_hls_executable')
+
+    return ale#handlers#haskell_stack#EscapeExecutable(l:executable,
+    \ 'haskell-language-server-wrapper')
+    \ . ' --lsp'
+endfunction
+
+call ale#linter#Define('haskell', {
+\   'name': 'hls',
+\   'lsp': 'stdio',
+\   'command': function('ale_linters#haskell#hls#GetCommand'),
+\   'executable': {b -> ale#Var(b, 'haskell_hls_executable')},
+\   'project_root': function('ale_linters#haskell#hls#GetProjectRoot'),
+\})
-- 
cgit v1.2.3