From 801c12a8813deb6ab20107fe8de979b86297b536 Mon Sep 17 00:00:00 2001
From: Magnus Ottenklinger <evnu@posteo.de>
Date: Wed, 23 Aug 2017 09:03:13 +0200
Subject: Add mix linter for elixir

---
 ale_linters/elixir/mix.vim | 42 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 ale_linters/elixir/mix.vim

(limited to 'ale_linters/elixir/mix.vim')

diff --git a/ale_linters/elixir/mix.vim b/ale_linters/elixir/mix.vim
new file mode 100644
index 00000000..41cd18a0
--- /dev/null
+++ b/ale_linters/elixir/mix.vim
@@ -0,0 +1,42 @@
+" Author: evnu - https://github.com/evnu
+" Author: colbydehart - https://github.com/colbydehart
+
+function! ale_linters#elixir#mix#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    "
+    " Error format
+    " ** (CompileError) apps/sim/lib/sim/server.ex:87: undefined function update_in/4
+    "
+    " TODO: Warning format
+    " warning: variable "foobar" does not exist and is being expanded to "foobar()", please use parentheses to remove the ambiguity or change the variable name
+
+    let l:pattern = '\v\(([^\)]+Error)\) ([^:]+):([^:]+): (.+)$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        let l:type = 'E'
+        let l:text = l:match[4]
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[3] + 0,
+        \   'col': 0,
+        \   'type': l:type,
+        \   'text': l:text,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale_linters#elixir#mix#Command(buffer) abort
+    let l:project_dir = fnamemodify(ale#path#FindNearestFile(a:buffer, 'mix.exs'), ':h')
+    return  'cd ' . l:project_dir . ' && mix compile %s'
+endfunction
+
+call ale#linter#Define('elixir', {
+\   'name': 'mix',
+\   'executable': 'mix',
+\   'command_callback': 'ale_linters#elixir#mix#Command',
+\   'callback': 'ale_linters#elixir#mix#Handle',
+\})
-- 
cgit v1.2.3