2 files changed, 98 insertions, 0 deletions
diff --git a/ale_linters/html/htmlhint.vim b/ale_linters/html/htmlhint.vim
new file mode 100644
index 00000000..8cfe1f28
--- /dev/null
+++ b/ale_linters/html/htmlhint.vim
@@ -0,0 +1,48 @@
+" Author: KabbAmine <amine.kabb@gmail.com>
+" Description: HTMLHint for checking html files
+
+if exists('g:loaded_ale_linters_html_htmlhint')
+    finish
+endif
+
+let g:loaded_ale_linters_html_htmlhint = 1
+
+function! ale_linters#html#htmlhint#Handle(buffer, lines) abort
+    " Matches patterns lines like the following:
+    "stdin:7:10: <title></title> must not be empty. [error/title-require]
+
+    let pattern = '^stdin:\(\d\+\):\(\d\+\): \(.\+\)$'
+    let output = []
+
+    for line in a:lines
+        let match = matchlist(line, pattern)
+
+        if len(match) == 0
+            continue
+        endif
+
+        let line = match[1] + 0
+        let col = match[2] + 0
+        let text = match[3]
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': line,
+        \   'vcol': 0,
+        \   'col': col,
+        \   'text': text,
+        \   'type': 'E',
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('html', {
+\   'name': 'htmlhint',
+\   'executable': 'htmlhint',
+\   'command': 'htmlhint --format=unix stdin',
+\   'callback': 'ale_linters#html#htmlhint#Handle',
+\})
diff --git a/ale_linters/verilog/verilator.vim b/ale_linters/verilog/verilator.vim
new file mode 100644
index 00000000..ef0c6b3c
--- /dev/null
+++ b/ale_linters/verilog/verilator.vim
@@ -0,0 +1,50 @@
+if exists('g:loaded_ale_linters_verilog_verilator')
+    finish
+endif
+
+let g:loaded_ale_linters_verilog_verilator = 1
+
+function! ale_linters#verilog#verilator#Handle(buffer, lines)
+    " Look for lines like the following.
+    "
+    " %Error: addr_gen.v:3: syntax error, unexpected IDENTIFIER
+    " %Warning-WIDTH: addr_gen.v:26: Operator ASSIGNDLY expects 12 bits on the Assign RHS, but Assign RHS's CONST '20'h0' generates 20 bits.
+    " %Warning-UNUSED: test.v:3: Signal is not used: a
+    " %Warning-UNDRIVEN: test.v:3: Signal is not driven: clk
+    " %Warning-UNUSED: test.v:4: Signal is not used: dout
+    " %Warning-BLKSEQ: test.v:10: Blocking assignments (=) in sequential (flop or latch) block; suggest delayed assignments (<=).
+    let pattern = '^%\(Warning\|Error\)[^:]*:[^:]\+:\(\d\+\): \(.\+\)$'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        let line = l:match[2] + 0
+        let type = l:match[1] ==# 'Error' ? 'E' : 'W'
+        let text = l:match[3]
+
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': line,
+        \   'vcol': 0,
+        \   'col': 1,
+        \   'text': text,
+        \   'type': type,
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('verilog', {
+\   'name': 'verilator',
+\   'output_stream': 'stderr',
+\   'executable': 'verilator',
+\   'command': g:ale#util#stdin_wrapper . ' .v verilator --lint-only -Wall -Wno-DECLFILENAME',
+\   'callback': 'ale_linters#verilog#verilator#Handle',
+\})