3 files changed, 121 insertions, 0 deletions
diff --git a/ale_linters/cpp/gcc.vim b/ale_linters/cpp/gcc.vim
new file mode 100644
index 00000000..31c3c245
--- /dev/null
+++ b/ale_linters/cpp/gcc.vim
@@ -0,0 +1,23 @@
+" Author: geam <mdelage@student.42.fr>
+" Description: gcc linter for cpp files
+
+if exists('g:loaded_ale_linters_cpp_gcc')
+    finish
+endif
+
+let g:loaded_ale_linters_cpp_gcc = 1
+
+" Set this option to change the GCC options for warnings for C.
+if !exists('g:ale_cpp_gcc_options')
+    let g:ale_cpp_gcc_options = '-Wall'
+endif
+
+call ALEAddLinter('cpp', {
+\   'name': 'gcc',
+\   'output_stream': 'stderr',
+\   'executable': 'gcc',
+\   'command': 'gcc -S -x c++ -fsyntax-only '
+\       . g:ale_cpp_gcc_options
+\       . ' -',
+\   'callback': 'ale#handlers#HandleGCCFormat',
+\})
diff --git a/ale_linters/verilog/iverilog.vim b/ale_linters/verilog/iverilog.vim
new file mode 100644
index 00000000..f8ea1784
--- /dev/null
+++ b/ale_linters/verilog/iverilog.vim
@@ -0,0 +1,48 @@
+if exists('g:loaded_ale_linters_verilog_iverilog')
+    finish
+endif
+
+let g:loaded_ale_linters_verilog_iverilog = 1
+
+function! ale_linters#verilog#iverilog#Handle(buffer, lines)
+    " Look for lines like the following.
+    "
+    " tb_me_top.v:37: warning: Instantiating module me_top with dangling input port 1 (rst_n) floating.
+    " tb_me_top.v:17: syntax error
+    " memory_single_port.v:2: syntax error
+    " tb_me_top.v:17: error: Invalid module instantiation
+    let pattern = '^[^:]\+:\(\d\+\): \(warning\|error\|syntax error\)\(: \(.\+\)\)\?'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        let line = l:match[1] + 0
+        let type = l:match[2] ==# 'warning' ? 'W' : 'E'
+        let text = l:match[2] ==# 'syntax error' ? 'syntax error' : l:match[4]
+
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': line,
+        \   'vcol': 0,
+        \   'col': 1,
+        \   'text': text,
+        \   'type': type,
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('verilog', {
+\   'name': 'iverilog',
+\   'output_stream': 'stderr',
+\   'executable': 'iverilog',
+\   'command': g:ale#util#stdin_wrapper . ' .v iverilog -t null -Wall',
+\   'callback': 'ale_linters#verilog#iverilog#Handle',
+\})
diff --git a/ale_linters/verilog/verilator.vim b/ale_linters/verilog/verilator.vim
new file mode 100644
index 00000000..ef0c6b3c
--- /dev/null
+++ b/ale_linters/verilog/verilator.vim
@@ -0,0 +1,50 @@
+if exists('g:loaded_ale_linters_verilog_verilator')
+    finish
+endif
+
+let g:loaded_ale_linters_verilog_verilator = 1
+
+function! ale_linters#verilog#verilator#Handle(buffer, lines)
+    " Look for lines like the following.
+    "
+    " %Error: addr_gen.v:3: syntax error, unexpected IDENTIFIER
+    " %Warning-WIDTH: addr_gen.v:26: Operator ASSIGNDLY expects 12 bits on the Assign RHS, but Assign RHS's CONST '20'h0' generates 20 bits.
+    " %Warning-UNUSED: test.v:3: Signal is not used: a
+    " %Warning-UNDRIVEN: test.v:3: Signal is not driven: clk
+    " %Warning-UNUSED: test.v:4: Signal is not used: dout
+    " %Warning-BLKSEQ: test.v:10: Blocking assignments (=) in sequential (flop or latch) block; suggest delayed assignments (<=).
+    let pattern = '^%\(Warning\|Error\)[^:]*:[^:]\+:\(\d\+\): \(.\+\)$'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        let line = l:match[2] + 0
+        let type = l:match[1] ==# 'Error' ? 'E' : 'W'
+        let text = l:match[3]
+
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': line,
+        \   'vcol': 0,
+        \   'col': 1,
+        \   'text': text,
+        \   'type': type,
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('verilog', {
+\   'name': 'verilator',
+\   'output_stream': 'stderr',
+\   'executable': 'verilator',
+\   'command': g:ale#util#stdin_wrapper . ' .v verilator --lint-only -Wall -Wno-DECLFILENAME',
+\   'callback': 'ale_linters#verilog#verilator#Handle',
+\})