Add hamllint linter for Haml (#377)

* Add hamllint linter for Haml

* Simplify hamllint

1 files changed, 33 insertions, 0 deletions

diff --git a/ale_linters/haml/hamllint.vim b/ale_linters/haml/hamllint.vim
new file mode 100644
index 00000000..fead7472
--- /dev/null
+++ b/ale_linters/haml/hamllint.vim
@@ -0,0 +1,33 @@
+" Author: Patrick Lewis - https://github.com/patricklewis
+" Description: haml-lint for Haml files
+
+function! ale_linters#haml#hamllint#Handle(buffer, lines) abort
+    " Matches patterns like the following:
+    " <path>:51 [W] RuboCop: Use the new Ruby 1.9 hash syntax.
+    let l:pattern = '\v^.*:(\d+) \[([EW])\] (.+)$'
+    let l:output = []
+
+    for l:line in a:lines
+        let l:match = matchlist(l:line, l:pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'type': l:match[2],
+        \   'text': l:match[3]
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('haml', {
+\   'name': 'hamllint',
+\   'executable': 'haml-lint',
+\   'command': 'haml-lint %t',
+\   'callback': 'ale_linters#haml#hamllint#Handle'
+\})