Dockerfile linting via hadolint (#282)

* Add hadolint linter for Dockerfiles

* Fix path

* Fix typo

* Update docs

1 files changed, 45 insertions, 0 deletions

diff --git a/ale_linters/dockerfile/hadolint.vim b/ale_linters/dockerfile/hadolint.vim
new file mode 100644
index 00000000..dc8e642c
--- /dev/null
+++ b/ale_linters/dockerfile/hadolint.vim
@@ -0,0 +1,45 @@
+" Author: hauleth - https://github.com/hauleth
+
+function! ale_linters#dockerfile#hadolint#Handle(buffer, lines) abort
+  " Matches patterns line the following:
+  "
+  " stdin:19: F: Pipe chain should start with a raw value.
+  let l:pattern = '\v^/dev/stdin:?(\d+)? (\S+) (.+)$'
+  let l:output = []
+
+  for l:line in a:lines
+    let l:match = matchlist(l:line, l:pattern)
+
+    if len(l:match) == 0
+        continue
+    endif
+
+    let l:lnum = 0
+
+    if l:match[1] !=# ''
+        let l:lnum = l:match[1] + 0
+    endif
+
+    let l:type = 'W'
+    let l:text = l:match[3]
+
+    " vcol is Needed to indicate that the column is a character.
+    call add(l:output, {
+    \   'bufnr': a:buffer,
+    \   'lnum': l:lnum,
+    \   'vcol': 0,
+    \   'col': 0,
+    \   'type': l:type,
+    \   'text': l:text,
+    \   'nr': l:match[2],
+    \})
+  endfor
+
+  return l:output
+endfunction
+
+call ale#linter#Define('dockerfile', {
+      \ 'name': 'hadolint',
+      \ 'executable': 'hadolint',
+      \ 'command': 'hadolint -',
+      \ 'callback': 'ale_linters#dockerfile#hadolint#Handle' })