Merge pull request #2056 from luan/virtualtext

Add support for nvim's virtualtext on cursor

9 files changed, 176 insertions, 16 deletions

diff --git a/autoload/ale/cursor.vim b/autoload/ale/cursor.vim
index 32ce8c84..6672c349 100644
--- a/autoload/ale/cursor.vim
+++ b/autoload/ale/cursor.vim
@@ -52,16 +52,6 @@ function! ale#cursor#TruncatedEcho(original_message) abort
     endtry
 endfunction
 
-function! s:FindItemAtCursor(buffer) abort
-    let l:info = get(g:ale_buffer_info, a:buffer, {})
-    let l:loclist = get(l:info, 'loclist', [])
-    let l:pos = getcurpos()
-    let l:index = ale#util#BinarySearch(l:loclist, a:buffer, l:pos[1], l:pos[2])
-    let l:loc = l:index >= 0 ? l:loclist[l:index] : {}
-
-    return [l:info, l:loc]
-endfunction
-
 function! s:StopCursorTimer() abort
     if s:cursor_timer != -1
         call timer_stop(s:cursor_timer)
@@ -85,7 +75,7 @@ function! ale#cursor#EchoCursorWarning(...) abort
         return
     endif
 
-    let [l:info, l:loc] = s:FindItemAtCursor(l:buffer)
+    let [l:info, l:loc] = ale#util#FindItemAtCursor(l:buffer)
 
     if g:ale_echo_cursor
         if !empty(l:loc)
@@ -169,7 +159,7 @@ function! ale#cursor#ShowCursorDetail() abort
 
     call s:StopCursorTimer()
 
-    let [l:info, l:loc] = s:FindItemAtCursor(l:buffer)
+    let [l:info, l:loc] = ale#util#FindItemAtCursor(l:buffer)
 
     if !empty(l:loc)
         call s:ShowCursorDetailForItem(l:loc, {'stay_here': 0})
diff --git a/autoload/ale/debugging.vim b/autoload/ale/debugging.vim
index 34c13770..6c2bfbee 100644
--- a/autoload/ale/debugging.vim
+++ b/autoload/ale/debugging.vim
@@ -22,14 +22,14 @@ let s:global_variable_list = [
 \    'ale_lint_delay',
 \    'ale_lint_on_enter',
 \    'ale_lint_on_filetype_changed',
+\    'ale_lint_on_insert_leave',
 \    'ale_lint_on_save',
 \    'ale_lint_on_text_changed',
-\    'ale_lint_on_insert_leave',
 \    'ale_linter_aliases',
 \    'ale_linters',
 \    'ale_linters_explicit',
-\    'ale_list_window_size',
 \    'ale_list_vertical',
+\    'ale_list_window_size',
 \    'ale_loclist_msg_format',
 \    'ale_max_buffer_history_size',
 \    'ale_max_signs',
@@ -52,6 +52,7 @@ let s:global_variable_list = [
 \    'ale_statusline_format',
 \    'ale_type_map',
 \    'ale_use_global_executables',
+\    'ale_virtualtext_cursor',
 \    'ale_warn_about_trailing_blank_lines',
 \    'ale_warn_about_trailing_whitespace',
 \]
diff --git a/autoload/ale/engine.vim b/autoload/ale/engine.vim
index e85e4d66..b44be73c 100644
--- a/autoload/ale/engine.vim
+++ b/autoload/ale/engine.vim
@@ -304,6 +304,12 @@ function! ale#engine#SetResults(buffer, loclist) abort
             call ale#cursor#EchoCursorWarning()
         endif
 
+        if g:ale_virtualtext_cursor
+            " Try and show the warning now.
+            " This will only do something meaningful if we're in normal mode.
+            call ale#virtualtext#ShowCursorWarning()
+        endif
+
         " Reset the save event marker, used for opening windows, etc.
         call setbufvar(a:buffer, 'ale_save_event_fired', 0)
         " Set a marker showing how many times a buffer has been checked.
diff --git a/autoload/ale/events.vim b/autoload/ale/events.vim
index 61a625df..c3dbd378 100644
--- a/autoload/ale/events.vim
+++ b/autoload/ale/events.vim
@@ -139,6 +139,14 @@ function! ale#events#Init() abort
                 autocmd InsertLeave * if exists('*ale#engine#Cleanup') | call ale#cursor#EchoCursorWarning() | endif
             endif
 
+            if g:ale_virtualtext_cursor
+                autocmd CursorMoved,CursorHold * if exists('*ale#engine#Cleanup') | call ale#virtualtext#ShowCursorWarningWithDelay() | endif
+                " Look for a warning to echo as soon as we leave Insert mode.
+                " The script's position variable used when moving the cursor will
+                " not be changed here.
+                autocmd InsertLeave * if exists('*ale#engine#Cleanup') | call ale#virtualtext#ShowCursorWarning() | endif
+            endif
+
             if g:ale_close_preview_on_insert
                 autocmd InsertEnter * if exists('*ale#preview#CloseIfTypeMatches') | call ale#preview#CloseIfTypeMatches('ale-preview') | endif
             endif
diff --git a/autoload/ale/util.vim b/autoload/ale/util.vim
index e0491653..bb478957 100644
--- a/autoload/ale/util.vim
+++ b/autoload/ale/util.vim
@@ -452,3 +452,14 @@ function! ale#util#Col(str, chr) abort
 
     return strlen(join(split(a:str, '\zs')[0:a:chr - 2], '')) + 1
 endfunction
+
+function! ale#util#FindItemAtCursor(buffer) abort
+    let l:info = get(g:ale_buffer_info, a:buffer, {})
+    let l:loclist = get(l:info, 'loclist', [])
+    let l:pos = getcurpos()
+    let l:index = ale#util#BinarySearch(l:loclist, a:buffer, l:pos[1], l:pos[2])
+    let l:loc = l:index >= 0 ? l:loclist[l:index] : {}
+
+    return [l:info, l:loc]
+endfunction
+
diff --git a/autoload/ale/virtualtext.vim b/autoload/ale/virtualtext.vim
new file mode 100644
index 00000000..85a12de6
--- /dev/null
+++ b/autoload/ale/virtualtext.vim
@@ -0,0 +1,104 @@
+scriptencoding utf-8
+" Author: w0rp <devw0rp@gmail.com>
+" Author: Luan Santos <cfcluan@gmail.com>
+" Description: Shows lint message for the current line as virtualtext, if any
+
+" Controls the milliseconds delay before showing a message.
+let g:ale_virtualtext_delay = get(g:, 'ale_virtualtext_delay', 10)
+let s:cursor_timer = -1
+let s:last_pos = [0, 0, 0]
+
+function! ale#virtualtext#Clear() abort
+    if !has('nvim-0.3.2')
+        return
+    endif
+
+    let l:buffer = bufnr('')
+
+    call nvim_buf_clear_highlight(l:buffer, 1000, 0, -1)
+endfunction
+
+function! ale#virtualtext#ShowMessage(message, hl_group) abort
+    if !has('nvim-0.3.2')
+        return
+    endif
+
+    let l:cursor_position = getcurpos()
+    let l:line = line('.')
+    let l:buffer = bufnr('')
+    let l:prefix = get(g:, 'ale_virtualtext_prefix', '> ')
+
+    call nvim_buf_set_virtual_text(l:buffer, 1000, l:line-1, [[l:prefix.a:message, a:hl_group]], {})
+endfunction
+
+function! s:StopCursorTimer() abort
+    if s:cursor_timer != -1
+        call timer_stop(s:cursor_timer)
+        let s:cursor_timer = -1
+    endif
+endfunction
+
+function! ale#virtualtext#ShowCursorWarning(...) abort
+    if !g:ale_virtualtext_cursor
+        return
+    endif
+
+    let l:buffer = bufnr('')
+
+    if mode(1) isnot# 'n'
+        return
+    endif
+
+    if ale#ShouldDoNothing(l:buffer)
+        return
+    endif
+
+    let [l:info, l:loc] = ale#util#FindItemAtCursor(l:buffer)
+
+    call ale#virtualtext#Clear()
+
+    if !empty(l:loc)
+        let l:msg = get(l:loc, 'detail', l:loc.text)
+        let l:hl_group = 'ALEInfo'
+        let l:type = get(l:loc, 'type', 'E')
+
+        if l:type is# 'E'
+            let l:hl_group = 'ALEError'
+        elseif l:type is# 'W'
+            let l:hl_group = 'ALEWarning'
+        endif
+
+        call ale#virtualtext#ShowMessage(l:msg, l:hl_group)
+    endif
+endfunction
+
+function! ale#virtualtext#ShowCursorWarningWithDelay() abort
+    let l:buffer = bufnr('')
+
+    if !g:ale_virtualtext_cursor
+        return
+    endif
+
+    if mode(1) isnot# 'n'
+        return
+    endif
+
+    call s:StopCursorTimer()
+
+    let l:pos = getcurpos()[0:2]
+
+    " Check the current buffer, line, and column number against the last
+    " recorded position. If the position has actually changed, *then*
+    " we should show something. Otherwise we can end up doing processing
+    " the show message far too frequently.
+    if l:pos != s:last_pos
+        let l:delay = ale#Var(l:buffer, 'virtualtext_delay')
+
+        let s:last_pos = l:pos
+        let s:cursor_timer = timer_start(
+        \   l:delay,
+        \   function('ale#virtualtext#ShowCursorWarning')
+        \)
+    endif
+endfunction
+
diff --git a/doc/ale.txt b/doc/ale.txt
index d619e526..5da95930 100644
--- a/doc/ale.txt
+++ b/doc/ale.txt
@@ -557,6 +557,7 @@ their relevant options.
 * By setting error highlights.                     - |g:ale_set_highlights|
 * By creating signs in the sign column.            - |g:ale_set_signs|
 * By echoing messages based on your cursor.        - |g:ale_echo_cursor|
+* By inline text based on your cursor.             - |g:ale_virtualtext_cursor|
 * By displaying the preview based on your cursor.  - |g:ale_cursor_detail|
 * By showing balloons for your mouse cursor        - |g:ale_set_balloons|
 
@@ -1873,6 +1874,41 @@ g:ale_use_global_executables                     *g:ale_use_global_executables*
   options.
 
 
+g:ale_virtualtext_cursor                                           *g:ale_virtualtext_cursor*
+
+  Type: |Number|
+  Default: `0`
+
+  When this option is set to `1`, a message will be shown when a cursor is
+  near a warning or error. ALE will attempt to find the warning or error at a
+  column nearest to the cursor when the cursor is resting on a line which
+  contains a warning or error. This option can be set to `0` to disable this
+  behavior.
+
+  Messages are only displayed after a short delay. See |g:ale_virtualtext_delay|.
+
+  Messages can be prefixed prefixed with a string. See |g:ale_virtualtext_prefix|.
+
+
+g:ale_virtualtext_delay                                             *g:ale_virtualtext_delay*
+                                                             *b:ale_virtualtext_delay*
+  Type: |Number|
+  Default: `10`
+
+  Given any integer, this option controls the number of milliseconds before
+  ALE will show a message for a problem near the cursor.
+
+  The value can be increased to decrease the amount of processing ALE will do
+  for files displaying a large number of problems.
+
+
+g:ale_virtualtext_prefix                                           *g:ale_virtualtext_prefix*
+
+  Type: |String|
+  Default: `'> '`
+
+  Prefix to be used with |g:ale_virtualtext_cursor|.
+
 g:ale_virtualenv_dir_names                         *g:ale_virtualenv_dir_names*
 b:ale_virtualenv_dir_names                         *b:ale_virtualenv_dir_names*
 
diff --git a/plugin/ale.vim b/plugin/ale.vim
index 7ef19775..7231d1bd 100644
--- a/plugin/ale.vim
+++ b/plugin/ale.vim
@@ -112,6 +112,9 @@ let g:ale_echo_cursor = get(g:, 'ale_echo_cursor', 1)
 " This flag can be set to 1 to automatically show errors in the preview window.
 let g:ale_cursor_detail = get(g:, 'ale_cursor_detail', 0)
 
+" This flag can be set to 1 to enable virtual text when the cursor moves.
+let g:ale_virtualtext_cursor = get(g:, 'ale_virtualtext_cursor', 0)
+
 " This flag can be set to 1 to automatically close the preview window upon
 " entering Insert Mode.
 let g:ale_close_preview_on_insert = get(g:, 'ale_close_preview_on_insert', 0)
diff --git a/test/test_ale_info.vader b/test/test_ale_info.vader
index 39a2a85a..325c2aa8 100644
--- a/test/test_ale_info.vader
+++ b/test/test_ale_info.vader
@@ -88,14 +88,14 @@ Before:
   \  'let g:ale_lint_delay = 200',
   \  'let g:ale_lint_on_enter = 1',
   \  'let g:ale_lint_on_filetype_changed = 1',
+  \  'let g:ale_lint_on_insert_leave = 0',
   \  'let g:ale_lint_on_save = 1',
   \  'let g:ale_lint_on_text_changed = ''always''',
-  \  'let g:ale_lint_on_insert_leave = 0',
   \  'let g:ale_linter_aliases = {}',
   \  'let g:ale_linters = {}',
   \  'let g:ale_linters_explicit = 0',
-  \  'let g:ale_list_window_size = 10',
   \  'let g:ale_list_vertical = 0',
+  \  'let g:ale_list_window_size = 10',
   \  'let g:ale_loclist_msg_format = ''%code: %%s''',
   \  'let g:ale_max_buffer_history_size = 20',
   \  'let g:ale_max_signs = -1',
@@ -118,6 +118,7 @@ Before:
   \  'let g:ale_statusline_format = [''%d error(s)'', ''%d warning(s)'', ''OK'']',
   \  'let g:ale_type_map = {}',
   \  'let g:ale_use_global_executables = v:null',
+  \  'let g:ale_virtualtext_cursor = 0',
   \  'let g:ale_warn_about_trailing_blank_lines = 1',
   \  'let g:ale_warn_about_trailing_whitespace = 1',
   \]