#335 Detect flake8 in vritualenv, and escape the executable path

4 files changed, 109 insertions, 5 deletions

diff --git a/ale_linters/python/flake8.vim b/ale_linters/python/flake8.vim
index a30dc03b..ab074567 100644
--- a/ale_linters/python/flake8.vim
+++ b/ale_linters/python/flake8.vim
@@ -8,15 +8,32 @@ let g:ale_python_flake8_executable =
 let s:default_options = get(g:, 'ale_python_flake8_args', '')
 let g:ale_python_flake8_options =
 \   get(g:, 'ale_python_flake8_options', s:default_options)
+let g:ale_python_flake8_use_global = get(g:, 'ale_python_flake8_use_global', 0)
 
 " A map from Python executable paths to semver strings parsed for those
 " executables, so we don't have to look up the version number constantly.
 let s:version_cache = {}
 
 function! ale_linters#python#flake8#GetExecutable(buffer) abort
+    if !ale#Var(a:buffer, 'python_flake8_use_global')
+        let l:virtualenv = ale#python#FindVirtualenv(a:buffer)
+
+        if !empty(l:virtualenv)
+            let l:ve_flake8 = l:virtualenv . '/bin/flake8'
+
+            if executable(l:ve_flake8)
+                return l:ve_flake8
+            endif
+        endif
+    endif
+
     return ale#Var(a:buffer, 'python_flake8_executable')
 endfunction
 
+function! ale_linters#python#flake8#ClearVersionCache() abort
+    let s:version_cache = {}
+endfunction
+
 function! ale_linters#python#flake8#VersionCheck(buffer) abort
     let l:executable = ale_linters#python#flake8#GetExecutable(a:buffer)
 
@@ -27,7 +44,8 @@ function! ale_linters#python#flake8#VersionCheck(buffer) abort
         return ''
     endif
 
-    return ale_linters#python#flake8#GetExecutable(a:buffer) . ' --version'
+    return fnameescape(ale_linters#python#flake8#GetExecutable(a:buffer))
+    \   . ' --version'
 endfunction
 
 " Get the flake8 version from the output, or the cache.
@@ -60,12 +78,14 @@ function! ale_linters#python#flake8#GetCommand(buffer, version_output) abort
     " Only include the --stdin-display-name argument if we can parse the
     " flake8 version, and it is recent enough to support it.
     let l:display_name_args = s:SupportsDisplayName(l:version)
-    \   ? '--stdin-display-name %s'
+    \   ? ' --stdin-display-name %s'
     \   : ''
 
-    return ale_linters#python#flake8#GetExecutable(a:buffer)
-    \   . ' ' . ale#Var(a:buffer, 'python_flake8_options')
-    \   . ' ' . l:display_name_args . ' -'
+    let l:options = ale#Var(a:buffer, 'python_flake8_options')
+
+    return fnameescape(ale_linters#python#flake8#GetExecutable(a:buffer))
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . l:display_name_args . ' -'
 endfunction
 
 call ale#linter#Define('python', {
diff --git a/doc/ale-python.txt b/doc/ale-python.txt
index 00aa9b38..29646714 100644
--- a/doc/ale-python.txt
+++ b/doc/ale-python.txt
@@ -31,6 +31,18 @@ g:ale_python_flake8_options                       *g:ale_python_flake8_options*
   `python3 -m pip install --user flake8`).
 
 
+g:ale_python_flake8_use_global                 *g:ale_python_flake8_use_global*
+                                               *b:ale_python_flake8_use_global*
+  Type: |Number|
+  Default: `0`
+
+  This variable controls whether or not ALE will search for flake8 in a
+  virtualenv directory first. If this variable is set to `1`, then ALE will
+  always use |g:ale_python_flake8_executable| for the executable path.
+
+  Both variables can be set with `b:` buffer variables instead.
+
+
 -------------------------------------------------------------------------------
 mypy                                                          *ale-python-mypy*
 
diff --git a/test/command_callback/python_paths/with_virtualenv/env/bin/flake8 b/test/command_callback/python_paths/with_virtualenv/env/bin/flake8
new file mode 100755
index 00000000..e69de29b
--- /dev/null
+++ b/test/command_callback/python_paths/with_virtualenv/env/bin/flake8
diff --git a/test/command_callback/test_flake8_command_callback.vader b/test/command_callback/test_flake8_command_callback.vader
new file mode 100644
index 00000000..bf4dfaff
--- /dev/null
+++ b/test/command_callback/test_flake8_command_callback.vader
@@ -0,0 +1,72 @@
+Before:
+  runtime ale_linters/python/flake8.vim
+  silent! execute 'cd /testplugin/test/command_callback'
+  let g:dir = getcwd()
+
+After:
+  silent execute 'cd ' . fnameescape(g:dir)
+  " Set the file to something else,
+  " or we'll cause issues when running other tests
+  silent file 'dummy.py'
+  unlet! g:dir
+
+  call ale#linter#Reset()
+  let g:ale_python_flake8_executable = 'flake8'
+  let g:ale_python_flake8_options = ''
+  let g:ale_python_flake8_use_global = 0
+
+  call ale_linters#python#flake8#ClearVersionCache()
+
+Execute(The flake8 callbacks should return the correct default values):
+  AssertEqual
+  \ 'flake8',
+  \ ale_linters#python#flake8#GetExecutable(bufnr(''))
+  AssertEqual
+  \ 'flake8 --version',
+  \ ale_linters#python#flake8#VersionCheck(bufnr(''))
+  AssertEqual
+  \ 'flake8 --stdin-display-name %s -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['3.0.0'])
+  " Try with older versions.
+  call ale_linters#python#flake8#ClearVersionCache()
+  AssertEqual
+  \ 'flake8 -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['2.9.9'])
+
+Execute(The flake8 command callback should let you set options):
+  let g:ale_python_flake8_options = '--some-option'
+
+  AssertEqual
+  \ 'flake8 --some-option --stdin-display-name %s -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['3.0.4'])
+  call ale_linters#python#flake8#ClearVersionCache()
+  AssertEqual
+  \ 'flake8 --some-option -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['2.9.9'])
+
+Execute(You should be able to set a custom executable and it should be escaped):
+  let g:ale_python_flake8_executable = 'executable with spaces'
+
+  AssertEqual
+  \ 'executable with spaces',
+  \ ale_linters#python#flake8#GetExecutable(bufnr(''))
+  AssertEqual
+  \ 'executable\ with\ spaces --version',
+  \ ale_linters#python#flake8#VersionCheck(bufnr(''))
+  AssertEqual
+  \ 'executable\ with\ spaces --stdin-display-name %s -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['3.0.0'])
+
+Execute(The flake8 callbacks should detect virtualenv directories):
+  silent execute 'file ' . fnameescape(g:dir . '/python_paths/with_virtualenv/subdir/foo/bar.py')
+
+  AssertEqual
+  \ g:dir . '/python_paths/with_virtualenv/env/bin/flake8',
+  \ ale_linters#python#flake8#GetExecutable(bufnr(''))
+  AssertEqual
+  \ g:dir . '/python_paths/with_virtualenv/env/bin/flake8 --version',
+  \ ale_linters#python#flake8#VersionCheck(bufnr(''))
+  AssertEqual
+  \   g:dir . '/python_paths/with_virtualenv/env/bin/flake8'
+  \   . ' --stdin-display-name %s -',
+  \ ale_linters#python#flake8#GetCommand(bufnr(''), ['3.0.0'])