Merge pull request #50 from jwilliams108/linter-phpcs

adding phpcs linter

3 files changed, 60 insertions, 2 deletions

diff --git a/README.md b/README.md
index 574e08ba..03bca3cf 100644
--- a/README.md
+++ b/README.md
@@ -37,7 +37,7 @@ name. That seems to be the fairest way to arrange this table.
 | HTML | [tidy](http://www.html-tidy.org/) |
 | JavaScript | [eslint](http://eslint.org/), [jscs](http://jscs.info/), [jshint](http://jshint.com/) |
 | JSON | [jsonlint](http://zaa.ch/jsonlint/) |
-| PHP | [php -l](https://secure.php.net/) |
+| PHP | [php -l](https://secure.php.net/), [phpcs](https://github.com/squizlabs/PHP_CodeSniffer) |
 | Python | [flake8](http://flake8.pycqa.org/en/latest/) |
 | Ruby   | [rubocop](https://github.com/bbatsov/rubocop) |
 | SASS | [sass-lint](https://www.npmjs.com/package/sass-lint) |
diff --git a/ale_linters/php/phpcs.vim b/ale_linters/php/phpcs.vim
new file mode 100644
index 00000000..62517c92
--- /dev/null
+++ b/ale_linters/php/phpcs.vim
@@ -0,0 +1,58 @@
+" Author: jwilliams108 <https://github.com/jwilliams108>
+" Description: phpcs for PHP files
+
+if exists('g:loaded_ale_linters_php_phpcs')
+    finish
+endif
+
+let g:loaded_ale_linters_php_phpcs = 1
+
+function! ale_linters#php#phpcs#GetCommand(buffer)
+    let command = 'phpcs -s --report=emacs --stdin-path=%s'
+
+    " This option can be set to change the standard used by phpcs
+    if exists('g:ale_linters_php_phpcs_standard')
+        let command .= ' --standard=' . g:ale_linters_php_phpcs_standard
+    endif
+
+    return command
+endfunction
+
+function! ale_linters#php#phpcs#Handle(buffer, lines)
+    " Matches against lines like the following:
+    "
+    " /path/to/some-filename.php:18:3: error - Line indented incorrectly; expected 4 spaces, found 2 (Generic.WhiteSpace.ScopeIndent.IncorrectExact)
+    let pattern = '^.*:\(\d\+\):\(\d\+\): \(.\+\) - \(.\+\) \(\(.\+\)\)$'
+    let output = []
+
+    for line in a:lines
+        let l:match = matchlist(line, pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        let text = l:match[4]
+        let type = l:match[3]
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'vcol': 0,
+        \   'col': l:match[2] + 0,
+        \   'text': text,
+        \   'type': type ==# 'warning' ? 'W' : 'E',
+        \   'nr': -1,
+        \})
+    endfor
+
+    return output
+endfunction
+
+call ALEAddLinter('php', {
+\   'name': 'phpcs',
+\   'executable': 'phpcs',
+\   'command_callback': 'ale_linters#php#phpcs#GetCommand',
+\   'callback': 'ale_linters#php#phpcs#Handle',
+\})
diff --git a/doc/ale.txt b/doc/ale.txt
index 369361c2..106802cb 100644
--- a/doc/ale.txt
+++ b/doc/ale.txt
@@ -46,7 +46,7 @@ The following languages and tools are supported.
 * HTML: 'tidy'
 * JavaScript: 'eslint', 'jscs', 'jshint'
 * JSON: 'jsonlint'
-* PHP: 'php' (-l flag)
+* PHP: 'php' (-l flag), 'phpcs'
 * Python: 'flake8'
 * Ruby: 'rubocop'
 * SASS: 'sasslint'