Introduce generic unix formatter

Two wrapper functions allow treating lines as errors or as warnings

4 files changed, 43 insertions, 92 deletions

diff --git a/ale_linters/go/gofmt.vim b/ale_linters/go/gofmt.vim
index d42d83eb..83c4d811 100644
--- a/ale_linters/go/gofmt.vim
+++ b/ale_linters/go/gofmt.vim
@@ -7,41 +7,11 @@ endif
 
 let g:loaded_ale_linters_go_gofmt = 1
 
-function! ale_linters#go#gofmt#Handle(buffer, lines)
-    " Matches patterns line the following:
-    "
-    " file1.go:5:2: expected declaration, found 'STRING' "log"
-    " file2.go:17:2: expected declaration, found 'go'
-    let l:pattern = '^.*:\(\d\+\):\(\d\+\): \(.\+\)$'
-    let l:output = []
-
-    for l:line in a:lines
-        let l:match = matchlist(l:line, l:pattern)
-
-        if len(l:match) == 0
-            continue
-        endif
-
-        " vcol is Needed to indicate that the column is a character.
-        call add(l:output, {
-        \   'bufnr': a:buffer,
-        \   'lnum': l:match[1] + 0,
-        \   'vcol': 0,
-        \   'col': l:match[2] + 0,
-        \   'text': l:match[3],
-        \   'type': 'E',
-        \   'nr': -1,
-        \})
-    endfor
-
-    return l:output
-endfunction
-
 call ale#linter#Define('go', {
 \   'name': 'gofmt',
 \   'output_stream': 'stderr',
 \   'executable': 'gofmt',
 \   'command': g:ale#util#stdin_wrapper . ' .go gofmt -e',
-\   'callback': 'ale_linters#go#gofmt#Handle',
+\   'callback': 'ale#handlers#HandleUnixFormatAsError',
 \})
 
diff --git a/ale_linters/go/golint.vim b/ale_linters/go/golint.vim
index 2e9c17bb..25787e0e 100644
--- a/ale_linters/go/golint.vim
+++ b/ale_linters/go/golint.vim
@@ -7,39 +7,9 @@ endif
 
 let g:loaded_ale_linters_go_golint = 1
 
-function! ale_linters#go#golint#Handle(buffer, lines)
-    " Matches patterns line the following:
-    "
-    " file1.go:53:10: if block ends with a return statement, so drop this else and outdent its block (move short variable declaration to its own line if necessary)
-    " file2.go:67:14: should omit type [][]byte from declaration of var matches; it will be inferred from the right-hand side
-    let l:pattern = '^.*:\(\d\+\):\(\d\+\): \(.\+\)$'
-    let l:output = []
-
-    for l:line in a:lines
-        let l:match = matchlist(l:line, l:pattern)
-
-        if len(l:match) == 0
-            continue
-        endif
-
-        " vcol is Needed to indicate that the column is a character.
-        call add(l:output, {
-        \   'bufnr': a:buffer,
-        \   'lnum': l:match[1] + 0,
-        \   'vcol': 0,
-        \   'col': l:match[2] + 0,
-        \   'text': l:match[3],
-        \   'type': 'W',
-        \   'nr': -1,
-        \})
-    endfor
-
-    return l:output
-endfunction
-
 call ale#linter#Define('go', {
 \   'name': 'golint',
 \   'executable': 'golint',
 \   'command': g:ale#util#stdin_wrapper . ' .go golint',
-\   'callback': 'ale_linters#go#golint#Handle',
+\   'callback': 'ale#handlers#HandleUnixFormatAsWarning',
 \})
diff --git a/ale_linters/go/govet.vim b/ale_linters/go/govet.vim
index 0ee5dd74..9db39ead 100644
--- a/ale_linters/go/govet.vim
+++ b/ale_linters/go/govet.vim
@@ -7,40 +7,11 @@ endif
 
 let g:loaded_ale_linters_go_govet = 1
 
-function! ale_linters#go#govet#Handle(buffer, lines)
-    " Matches patterns line the following:
-    "
-    " file.go:27: missing argument for Printf("%s"): format reads arg 2, have only 1 args
-    let l:pattern = '^.*:\(\d\+\): \(.\+\)$'
-    let l:output = []
-
-    for l:line in a:lines
-        let l:match = matchlist(l:line, l:pattern)
-
-        if len(l:match) == 0
-            continue
-        endif
-
-        " vcol is Needed to indicate that the column is a character.
-        call add(l:output, {
-        \   'bufnr': a:buffer,
-        \   'lnum': l:match[1] + 0,
-        \   'vcol': 0,
-        \   'col': 0,
-        \   'text': l:match[2],
-        \   'type': 'W',
-        \   'nr': -1,
-        \})
-    endfor
-
-    return l:output
-endfunction
-
 call ale#linter#Define('go', {
 \   'name': 'go vet',
 \   'output_stream': 'stderr',
 \   'executable': 'go',
 \   'command': g:ale#util#stdin_wrapper . ' .go go vet',
-\   'callback': 'ale_linters#go#govet#Handle',
+\   'callback': 'ale#handlers#HandleUnixFormatAsError',
 \})
 
diff --git a/autoload/ale/handlers.vim b/autoload/ale/handlers.vim
index e595ae48..ed846abb 100644
--- a/autoload/ale/handlers.vim
+++ b/autoload/ale/handlers.vim
@@ -4,6 +4,46 @@ scriptencoding utf-8
 "   linter which outputs warnings and errors in a format accepted by one of
 "   these functions can simply use one of these pre-defined error handlers.
 
+function! s:HandleUnixFormat(buffer, lines, type) abort
+    " Matches patterns line the following:
+    "
+    " file.go:27: missing argument for Printf("%s"): format reads arg 2, have only 1 args
+    " file.go:53:10: if block ends with a return statement, so drop this else and outdent its block (move short variable declaration to its own line if necessary)
+    " file.go:5:2: expected declaration, found 'STRING' "log"
+    let l:pattern = '^[^:]\+:\(\d\+\):\?\(\d\+\)\?: \(.\+\)$'
+    let l:output = []
+
+    for l:line in a:lines
+        let l:match = matchlist(l:line, l:pattern)
+
+        if len(l:match) == 0
+            continue
+        endif
+
+        " vcol is Needed to indicate that the column is a character.
+        call add(l:output, {
+        \   'bufnr': a:buffer,
+        \   'lnum': l:match[1] + 0,
+        \   'vcol': 0,
+        \   'col': l:match[2] + 0,
+        \   'text': l:match[3],
+        \   'type': a:type,
+        \   'nr': -1,
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+function! ale#handlers#HandleUnixFormatAsError(buffer, lines) abort
+    return s:HandleUnixFormat(a:buffer, a:lines, 'E')
+endfunction
+
+function! ale#handlers#HandleUnixFormatAsWarning(buffer, lines) abort
+    return s:HandleUnixFormat(a:buffer, a:lines, 'W')
+endfunction
+
+
 function! ale#handlers#HandleGCCFormat(buffer, lines) abort
     " Look for lines like the following.
     "