Add shellcheck as linter for bats files

4 files changed, 130 insertions, 0 deletions

diff --git a/ale_linters/bats/shellcheck.vim b/ale_linters/bats/shellcheck.vim
new file mode 100644
index 00000000..64130a2d
--- /dev/null
+++ b/ale_linters/bats/shellcheck.vim
@@ -0,0 +1,78 @@
+" Author: Ian2020 <https://github.com/Ian2020>
+" Description: This file adds support for using the shellcheck linter with
+"   bats scripts. Heavily inspired by/copied from work by w0rp on shellcheck
+"   for sh files.
+
+" This global variable can be set with a string of comma-separated error
+" codes to exclude from shellcheck. For example:
+"
+" let g:ale_bats_shellcheck_exclusions = 'SC2002,SC2004'
+call ale#Set('bats_shellcheck_exclusions', get(g:, 'ale_linters_bats_shellcheck_exclusions', ''))
+call ale#Set('bats_shellcheck_executable', 'shellcheck')
+call ale#Set('bats_shellcheck_options', '')
+call ale#Set('bats_shellcheck_change_directory', 1)
+
+function! ale_linters#bats#shellcheck#GetCommand(buffer, version) abort
+    let l:options = ale#Var(a:buffer, 'bats_shellcheck_options')
+    let l:exclude_option = ale#Var(a:buffer, 'bats_shellcheck_exclusions')
+    let l:external_option = ale#semver#GTE(a:version, [0, 4, 0]) ? ' -x' : ''
+    let l:cd_string = ale#Var(a:buffer, 'bats_shellcheck_change_directory')
+    \   ? ale#path#BufferCdString(a:buffer)
+    \   : ''
+
+    return l:cd_string
+    \   . '%e'
+    \   . ' -s bats'
+    \   . (!empty(l:options) ? ' ' . l:options : '')
+    \   . (!empty(l:exclude_option) ? ' -e ' . l:exclude_option : '')
+    \   . l:external_option
+    \   . ' -f gcc -'
+endfunction
+
+function! ale_linters#bats#shellcheck#Handle(buffer, lines) abort
+    let l:pattern = '\v^([a-zA-Z]?:?[^:]+):(\d+):(\d+)?:? ([^:]+): (.+) \[([^\]]+)\]$'
+    let l:output = []
+
+    for l:match in ale#util#GetMatches(a:lines, l:pattern)
+        if l:match[4] is# 'error'
+            let l:type = 'E'
+        elseif l:match[4] is# 'note'
+            let l:type = 'I'
+        else
+            let l:type = 'W'
+        endif
+
+        let l:item = {
+        \   'lnum': str2nr(l:match[2]),
+        \   'type': l:type,
+        \   'text': l:match[5],
+        \   'code': l:match[6],
+        \}
+
+        if !empty(l:match[3])
+            let l:item.col = str2nr(l:match[3])
+        endif
+
+        " If the filename is something like <stdin>, <nofile> or -, then
+        " this is an error for the file we checked.
+        if l:match[1] isnot# '-' && l:match[1][0] isnot# '<'
+            let l:item['filename'] = l:match[1]
+        endif
+
+        call add(l:output, l:item)
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('bats', {
+\   'name': 'shellcheck',
+\   'executable': {buffer -> ale#Var(buffer, 'bats_shellcheck_executable')},
+\   'command': {buffer -> ale#semver#RunWithVersionCheck(
+\       buffer,
+\       ale#Var(buffer, 'bats_shellcheck_executable'),
+\       '%e --version',
+\       function('ale_linters#bats#shellcheck#GetCommand'),
+\   )},
+\   'callback': 'ale_linters#bats#shellcheck#Handle',
+\})
diff --git a/doc/ale-bats.txt b/doc/ale-bats.txt
new file mode 100644
index 00000000..2ad98402
--- /dev/null
+++ b/doc/ale-bats.txt
@@ -0,0 +1,48 @@
+===============================================================================
+ALE Bats Integration                                        *ale-bats-options*
+
+
+===============================================================================
+shellcheck                                                  *ale-bats-shellcheck*
+
+g:ale_bats_shellcheck_executable               *g:ale_bats_shellcheck_executable*
+                                               *b:ale_bats_shellcheck_executable*
+  Type: |String|
+  Default: `'shellcheck'`
+
+  This variable sets executable used for shellcheck.
+
+
+g:ale_bats_shellcheck_options                     *g:ale_bats_shellcheck_options*
+                                                  *b:ale_bats_shellcheck_options*
+  Type: |String|
+  Default: `''`
+
+  With this variable we are able to pass extra arguments for shellcheck
+  for shellcheck invocation.
+
+  For example, if we want shellcheck to follow external sources (`see SC1091`)
+  we can set the variable as such:
+>
+  let g:ale_bats_shellcheck_options = '-x'
+<
+
+
+g:ale_bats_shellcheck_change_directory   *g:ale_bats_shellcheck_change_directory*
+                                         *b:ale_bats_shellcheck_change_directory*
+  Type: |Number|
+  Default: `1`
+
+  If set to `1`, ALE will switch to the directory the shell file being
+  checked with `shellcheck` is in before checking it. This helps `shellcheck`
+  determine the path to sourced files more easily. This option can be turned
+  off if you want to control the directory `shellcheck` is executed from
+  yourself.
+
+
+    autocmd BufEnter PKGBUILD,.env
+    \   let b:ale_bats_shellcheck_exclusions = 'SC2034,SC2154,SC2164'
+<
+
+===============================================================================
+  vim:tw=78:ts=2:sts=2:sw=2:ft=help:norl:
diff --git a/doc/ale-supported-languages-and-tools.txt b/doc/ale-supported-languages-and-tools.txt
index 636985fb..9fe7bfe5 100644
--- a/doc/ale-supported-languages-and-tools.txt
+++ b/doc/ale-supported-languages-and-tools.txt
@@ -35,6 +35,8 @@ Notes:
   * `shell` (-n flag)
   * `shellcheck`
   * `shfmt`
+* Bats
+  * `shellcheck`
 * BibTeX
   * `bibclean`
 * Bourne Shell
diff --git a/supported-tools.md b/supported-tools.md
index d5c0c9d4..f7dd9676 100644
--- a/supported-tools.md
+++ b/supported-tools.md
@@ -44,6 +44,8 @@ formatting.
   * shell [-n flag](https://www.gnu.org/software/bash/manual/bash.html#index-set)
   * [shellcheck](https://www.shellcheck.net/)
   * [shfmt](https://github.com/mvdan/sh)
+* Bats
+  * [shellcheck](https://www.shellcheck.net/)
 * BibTeX
   * [bibclean](http://ftp.math.utah.edu/pub/bibclean/)
 * Bourne Shell