From 1ee7580557733bab22b764170958a0189810b3bb Mon Sep 17 00:00:00 2001
From: Roeland <10061147+roelandmoors@users.noreply.github.com>
Date: Sat, 9 Oct 2021 07:33:07 +0200
Subject: Add support for erblint (#3931)

* support for erblint

* fix tests

* test for handler

* wrong names

* typo

* doc layout

* CI failed?
---
 ale_linters/eruby/erblint.vim | 51 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 ale_linters/eruby/erblint.vim

(limited to 'ale_linters')

diff --git a/ale_linters/eruby/erblint.vim b/ale_linters/eruby/erblint.vim
new file mode 100644
index 00000000..19960185
--- /dev/null
+++ b/ale_linters/eruby/erblint.vim
@@ -0,0 +1,51 @@
+" Author: Roeland Moors - https://github.com/roelandmoors
+" based on the ale ruumba and robocop linters
+" Description: ERB Lint, support for https://github.com/Shopify/erb-lint
+
+call ale#Set('eruby_erblint_executable', 'erblint')
+call ale#Set('eruby_erblint_options', '')
+
+function! ale_linters#eruby#erblint#GetCommand(buffer) abort
+    let l:executable = ale#Var(a:buffer, 'eruby_erblint_executable')
+
+    return ale#ruby#EscapeExecutable(l:executable, 'erblint')
+    \   . ' --format json '
+    \   . ale#Var(a:buffer, 'eruby_erblint_options')
+    \   . ' --stdin %s'
+endfunction
+
+function! ale_linters#eruby#erblint#Handle(buffer, lines) abort
+    if empty(a:lines)
+        return []
+    endif
+
+    let l:errors = ale#util#FuzzyJSONDecode(a:lines[0], [])
+
+    if !has_key(l:errors, 'summary')
+    \|| l:errors['summary']['offenses'] == 0
+    \|| empty(l:errors['files'])
+        return []
+    endif
+
+    let l:output = []
+
+    for l:error in l:errors['files'][0]['offenses']
+        call add(l:output, {
+        \   'lnum': l:error['location']['start_line'] + 0,
+        \   'col': l:error['location']['start_column'] + 0,
+        \   'end_col': l:error['location']['last_column'] + 0,
+        \   'code': l:error['linter'],
+        \   'text': l:error['message'],
+        \   'type': 'W',
+        \})
+    endfor
+
+    return l:output
+endfunction
+
+call ale#linter#Define('eruby', {
+\   'name': 'erblint',
+\   'executable': {b -> ale#Var(b, 'eruby_erblint_executable')},
+\   'command': function('ale_linters#eruby#erblint#GetCommand'),
+\   'callback': 'ale_linters#eruby#erblint#Handle',
+\})
-- 
cgit v1.2.3